xBrowse, linha dupla

evertonlb · October 4, 2013

Ei pessoal, estou com uma necessidade nova... Preciso colocar dois campos na mesma coluna, um abaixo do outro..

O nome da disciplina e o nome do professor...

tentei com o CRLF, mas deu erro, no momento de montar o Browse. Como posso fazer isso?

Att.

Erciley Junior · October 4, 2013

Deu erro? Cade? ^^

Se aumentar a Altura da linha e usar CHR(13)+CHR(10) , vulgo CRLF, é pra dar certo, acredito

SAOliveira · October 4, 2013

oBrw:aCols[9]:bstrData:= {|| aArray[oBrw:nArrayAt][17]+CRLF+aArray[oBrw:nArrayAt][18] }

evertonlb · October 4, 2013

Ai Sergio.. obrigado pela resposta. No entanto ta dando o seguinte erro...

Error BASE/1005 Class: 'NIL' has no property: BSTRDATA

Não sei se pode me ajudar também nisso!!!

Att.

Theotokos · October 4, 2013

Ai Sergio.. obrigado pela resposta. No entanto ta dando o seguinte erro...

Error BASE/1005 Class: 'NIL' has no property: BSTRDATA

Não sei se pode me ajudar também nisso!!!

Att.

Vc está usando xBrowse mesmo? Posta a parte do seu código onde você utiliza o xBrowse...

Daniel Lopes Filho · October 5, 2013

com fw 6.2 nao possui esse recurso so versao acho eu 10.xxx

Erciley Junior · October 7, 2013

oBrw:nDataLines:=2


ADD COLUMN TO XBROWSE oBrw DATA aVet[oBrw:nArrayAT,01] PICT '99,999'                 SIZE 060 HEADER 'Grupo'

ADD COLUMN TO XBROWSE oBrw DATA aVet[oBrw:nArrayAT,02]                               SIZE 250 HEADER 'Descrição'

ADD COLUMN TO XBROWSE oBrw DATA aVet[oBrw:nArrayAT,03]+CRLF+aVet[oBrw:nArrayAT,04]   SIZE 250 HEADER 'Teste'

evertonlb · October 7, 2013

bom dia.

Meu código é esse:

        oXBrw8 := TXBrowse():New( oGrp3 )
        oXBrw8:nMarqueeStyle       := 5
        oXBrw8:nColDividerStyle    := 0
        oXBrw8:nRowDividerStyle    := 1
        oXBrw8:lColDividerComplete := .F.
        oXBrw8:nHeaderLines        := 2
        oXBrw8:nDataLines          := 2
        oXBrw8:lFooter             := .T.
        oXBrw8:nRecSelColor        := 14204813
        oXBrw8:cAlias              := "DISCIPLINA"
        oXBrw8:lRecordSelector     := .t.
        oXBrw8:lHScroll            := .f.                                
        oXBrw8:SetRDD()
        oXBrw8:CreateFromCode()
        oXBrw8:Move( 15.00, 5.00, 450.00, 215.00, .t. )
       
        aCol_oXBrw8[1] := oXBrw8:aCols[1]
           aCol_oXBrw8[1]:nWidth       := 80
           aCol_oXBrw8[1]:cHeader      := "Código"
           aCol_oXBrw8[1]:lHIDE        := .F.
           aCol_oXBrw8[1]:oHeaderFont  := oFONT1
           aCol_oXBrw8[1]:oDataFont    := oFONT1
           aCol_oXBrw8[1]:oFooterFont  := oFONT1
           aCol_oXBrw8[1]:bClrHeader   := {|| { 0, 14204813 } }
           aCol_oXBrw8[1]:bClrFooter   := {|| { 0, 15790320 } }
           aCol_oXBrw8[1]:bClrStd      := {|| { 0, 16777215 } }
           aCol_oXBrw8[1]:bClrSel      := {|| { 0, 6579300 } }
           aCol_oXBrw8[1]:bClrSelFocus := {|| { 0, 10806201 } }

        aCol_oXBrw8[1] := oXBrw8:aCols[3] + CRLF + oXBrw8:aCols[7] 
           aCol_oXBrw8[3]:nWidth       := 280
           aCol_oXBrw8[3]:cHeader      := "Disciplina"
           aCol_oXBrw8[3]:lHIDE        := .F.
           aCol_oXBrw8[3]:oHeaderFont  := oFONT1
           aCol_oXBrw8[3]:oDataFont    := oFONT1
           aCol_oXBrw8[3]:oFooterFont  := oFONT1
           aCol_oXBrw8[3]:bClrHeader   := {|| { 0, 14204813 } }
           aCol_oXBrw8[3]:bClrFooter   := {|| { 0, 15790320 } }
           aCol_oXBrw8[3]:bClrStd      := {|| { 0, 16777215 } }
           aCol_oXBrw8[3]:bClrSel      := {|| { 0, 6579300 } }
           aCol_oXBrw8[3]:bClrSelFocus := {|| { 0, 10806201 } }


		  aCol_oXBrw8[2] := oXBrw8:aCols[2]
        aCol_oXBrw8[2]:lHIDE        := .T.

        aCol_oXBrw8[4] := oXBrw8:aCols[4]
        aCol_oXBrw8[4]:lHIDE        := .T.
 
        aCol_oXBrw8[5] := oXBrw8:aCols[5]
        aCol_oXBrw8[5]:lHIDE        := .T.

        aCol_oXBrw8[6] := oXBrw8:aCols[6]
        aCol_oXBrw8[6]:lHIDE        := .T.

        aCol_oXBrw8[7] := oXBrw8:aCols[7]
        aCol_oXBrw8[7]:lHIDE        := .T.

        oXBrw8:refresh()

Tomara que seja possível colocar as duas linhas de dados...

aferra · October 7, 2013

Bom dia...acredito que o erro está na forma como vc carrega a xbrowse....é uma forma bem diferente das que eu já vi...interessante ...mas vamos lá. o que acredito ser a mudança para dar certo.

aCol_oXBrw8[1] := oXBrw8:aCols[3]

aCol_oXBrw8[3]:bstrData:= {|| DISCIPLINA-><campo1>+CRLF+DISCIPLINA-><campo2>}

Veja se dá certo.

Erciley Junior · October 7, 2013

oBrw:aCols[9]:bstrData:= {|| aArray[oBrw:nArrayAt][17]+CRLF+aArray[oBrw:nArrayAt][18] }

Olá Sérgio..... aproveitando o tópico, como você alterou a fonte e cor da informação que está na segunda linha? Ficaria grato.

Daniel Lopes Filho · October 7, 2013

pesquisando o 805 possui isso vou testar no examples existe o testxbrw.prg vou testar aqui

evertonlb · October 7, 2013

Na minha versão 6.12 ou 6.22 (free) tem, dentro do xBrowse.PRG o:

DATA bStrData,; // String data codeblock (returns a string)
bBmpData // Ordinal bitmap data codeblock (returns a
// number in the range 1-len(aBitmaps))

Na realidade, todas as formas que me foi passado, a cima, não deu certo!

tentei várias "variantes", e continuarei tentando... a única coisa que sei é que uma hora e de alguma maneira vai dar certo!

rsrsrsrsrsrsrs

Att.

marcioe · October 8, 2013

uma coisa que achei interessante é o lance de ter 02 cores na mesma linha

Se puder postar como que se faz agradeço

aferra · October 8, 2013

Teste esse código

oXBrw8 := TXBrowse():New( oGrp3 )
oXBrw8:nMarqueeStyle := 5
oXBrw8:nColDividerStyle := 0
oXBrw8:nRowDividerStyle := 1
oXBrw8:lColDividerComplete := .F.
oXBrw8:nHeaderLines := 2
oXBrw8:nDataLines := 2
oXBrw8:lFooter := .T.
oXBrw8:nRecSelColor := 14204813
oXBrw8:cAlias := "DISCIPLINA"
oXBrw8:lRecordSelector := .t.
oXBrw8:lHScroll := .f.
oXBrw8:SetRDD(.F.,.T.)

aCol_oXBrw8 := oXBrw8:addcol()
aCol_oXBrw8:cHeader := "Código"
aCol_oXBrw8:bStrdata := {|| DISCIPLINA-><codigo> }
aCol_oXBrw8:nWidth := 80
aCol_oXBrw8:lHIDE := .F.
aCol_oXBrw8:oHeaderFont := oFONT1
aCol_oXBrw8:oDataFont := oFONT1
aCol_oXBrw8:oFooterFont := oFONT1
aCol_oXBrw8:bClrHeader := {|| { 0, 14204813 } }
aCol_oXBrw8:bClrFooter := {|| { 0, 15790320 } }
aCol_oXBrw8:bClrStd := {|| { 0, 16777215 } }
aCol_oXBrw8:bClrSel := {|| { 0, 6579300 } }
aCol_oXBrw8:bClrSelFocus := {|| { 0, 10806201 } }

aCol_oXBrw8 := oXBrw8:addcol()
aCol_oXBrw8:cHeader := "Disciplina"
aCol_oXBrw8:bStrdata := {|| DISCIPLINA-><campo1> + DISCIPLINA-><campo2> }
aCol_oXBrw8:nWidth := 280
aCol_oXBrw8:lHIDE := .F.
aCol_oXBrw8:oHeaderFont := oFONT1
aCol_oXBrw8:oDataFont := oFONT1
aCol_oXBrw8:oFooterFont := oFONT1
aCol_oXBrw8:bClrHeader := {|| { 0, 14204813 } }
aCol_oXBrw8:bClrFooter := {|| { 0, 15790320 } }
aCol_oXBrw8:bClrStd := {|| { 0, 16777215 } }
aCol_oXBrw8:bClrSel := {|| { 0, 6579300 } }
aCol_oXBrw8:bClrSelFocus := {|| { 0, 10806201 } }

oXBrw8:CreateFromCode()
oXBrw8:Move( 15.00, 5.00, 450.00, 215.00, .t. )

evertonlb · October 8, 2013

Alessandro "Aferra". Não pude entrar no fórum hoje, mas deu certinho cara.. muito obrigado!!!

Att.

marcioe · October 9, 2013

amigos, que eu estava querendo era o seguinte

a segunda linha esta em preto e a primeira em azul, veja a imagem

aferra · October 9, 2013

Marcio, dê uma olhada neste link

http://forums.fivetechsupport.com/viewtopic.php?f=3&t=27136

Eduardo Bilato · October 9, 2013

Olá Sérgio..... aproveitando o tópico, como você alterou a fonte e cor da informação que está na segunda linha? Ficaria grato.

Também fiquei curioso pra saber isso

evertonlb · October 9, 2013

^{Nossa.. e eu que achava que a xBrowse servia só para mostrar alguns registros em colunas e linhas! hahahahahahaha}

^{Tenho muito para aprender ainda... isso é tudo que sei!!!!}

^Att.

Theotokos · October 9, 2013

Eu testei, fiz assim:

	oBrw := TxBrowse():New( oDlg )   
	oBrw:CreateFromResource( 4001 )   
	oBrw:cAlias := 'BanClien'   
	oBrw:lFastEdit := .t. 
	*
	ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_COND1	  TITLE "B"					   Size 20  ALIGN CENTERED
   ADD COLUMN TO XBROWSE oBrw DATA "Código : " + StrZero(BanClien->D_NUMERO,5)   TITLE "Nº" SIZE 300 ALIGN LEFT COLOR CLR_RED 
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_NOME     TITLE "Nome Cliente" 	   SIZE 300 ALIGN LEFT     
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_ENDERECO TITLE "Endereço"         SIZE 300 ALIGN LEFT
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_BAIRRO   TITLE "Bairro"           SIZE 200 ALIGN LEFT
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_CIDADE   TITLE "Cidade"           SIZE 200 ALIGN LEFT
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_CPF      TITLE "CPF/CNPJ"     	   SIZE 150 ALIGN LEFT
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_NASCIMEN TITLE "Dt.Nascimento" 	SIZE 090 ALIGN CENTERED
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_TELEFONE TITLE "Telefone"      	SIZE 150 ALIGN LEFT
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_CELULAR  TITLE "Celular"       	SIZE 150 ALIGN LEFT
   ADD COLUMN TO XBROWSE oBrw DATA BanClien->D_EMAIL    TITLE "E-Mail"        	SIZE 200 ALIGN LEFT
	*
	oBrw:aCols[2]:SetColsAsRows (2, 3)

funcionou, só que a linha de baixo (2º) sobrepõe a 1º linha, qual será o problema???

SAOliveira · October 9, 2013

oBrw:aCols[1]:bPaintText :={|oCol,hDC,cText,aCoord| PCS_MudaTextoXbrw( oCol, hDC, cText, aCoord, oPub:fNorm12, oPub:CorGet,oPub:CorGetW ) }

**-------------------------------------------------------------------------**
FUNCTION PCS_MudaTextoXbrw( oCol, hDC, cText, aCoord, oFonte,oCor1,oCor2 )
**-------------------------------------------------------------------------**
LOCAL nTop:=aCoord[ 1 ], nLeft := aCoord[ 2 ]
LOCAL nBottom:=aCoord[ 3 ], nRight := aCoord[ 4 ]
LOCAL nRow:= nTop
LOCAL cLine,nFontHt, nAt
LOCAL hBrush:=CreateSolidBrush( oPub:CorBege )

nAt:=AT(CRLF,cText )
IF(nAt>0)
cLine:=Left( cText, nAt - 1 )
SetTextColor( hDC, oCor1 )
nFontHt:=GetTextHeight( oCol:oBrw:hWnd, hDC )

DrawTextEx( hDC, cLine, { nRow, nLeft, nRow + nFontHt + 4, nRight }, oCol:nDataStyle )
nRow +=nFontHt + 4 //default 4
cLine:=SubStr( cText, nAt + 2 )
ELSE
cLine:=cText
ENDIF

DeleteObject( hBrush )
oFonte:Activate( hDC )
SetTextColor( hDC, oCor2 )
DrawTextEx( hDC, cLine, { nRow, nLeft, nBottom, nRight }, oCol:nDataStyle )
oFonte:DeActivate( hDC )

RETURN(NIL)

Eduardo Bilato · October 9, 2013

Valew Sergio

Erciley Junior · October 9, 2013

Obrigado Sérgio........ é disso q eu to falando ^^

xBrowse, linha dupla

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Join the conversation