Fastreport com DBF

SISCO · April 13, 2015

Estou fazendo alguns testes com Fastreport e utilizando DBF ao invés de array, mas quando imprime gera o relatório em branco, acredito que ele esteja indo para o final do arquivo.

Se alguém poder me ajudar ficarei grato,

kleyber · April 14, 2015

Podes postar teu código, por favor? Assim poderemos ver onde está o problema e te ajudar.

SISCO · April 14, 2015

SELECT TITULO

IF TITULO->(Recno()) == 0

MSGSTOP("Consulta Não Encontrada","Atenção")

RETURN .F.

ELSE

cImagem1 := ".\IMAGEM\logo.bmp"

RepDir := ".\REPORTS\"

cTitulo := "CONTAS CORRENTE EM ABERTO "

cTipo := "ENTIDADE"

oFrPrn := frReportManager():new()

oFrPrn:SetIcon(1) //ícone da janela do FRH

oFrPrn:SetTitle( cTitulo ) //título da janela do FRH

oFrPrn:SetTitle( cTipo ) //título da janela do FRH

oFrPrn:SetTitle( cImagem1 ) //título da janela do FRH

oFrPrn:LoadLangRes( 'brazil.xml') //arquivo de idioma

oFrPrn:SetWorkArea("TITULO", Select("TITULO"))

ENDIF

sambomb · April 14, 2015

Da um DbGoTop() nessa tabela, pode ser issso....

SISCO · April 15, 2015

Obrigado por responderem.

Fiz o gotop e nada, abaixo o restante do código

oFrPrn:LoadFromFile(RepDir+"REL_TITABE.FR3") // para leitura direta de arquivo FR3
oFrPrn:PreviewOptions:SetAllowEdit( .f. ) // inibe o botão de edição do relatório pelo usuário

oFrPrn:ShowReport()
oFrPrn:DestroyFR()

Theotokos · April 15, 2015

EU UTILIZO ASSIM, DÊ UMA OLHADA NESTAS DUAS LINHA EM VERMELHO E VÊ SE TE AJUDA...

FrPrn := frReportManager():New() //Abertura do FastReports

FrPrn:SetIcon(1) //Escolha do Ícone

FrPrn:SetTitle("Pedido - "+StrZero(nNumero,10)) //Titulo da Dialog no FastReports

*******************************************************************

FrPrn:LoadLangRes( cDirFr+"BRAZIL.XML")

*******************************************************************

nVrExame := 0.00

cMaterial:= ""

cExames := ""

*

cArqTmp := "Pedido_"

cCampo1 := ""

*

FrPrn:SetWorkArea(cArqTmp, 98, .f., {FR_RB_FIRST, FR_RE_LAST, 0})

FrPrn:SetUserDataSet( cArqTmp,cCampo1,;

{|| DbGoTop() }, ; //--> bGoTop

{|| DbSkip(1) }, ; //--> bSkipPlus

{|| DbSkip(-1)}, ; //--> bSkipMinus

{|| EOF() }, ; //--> bCheckEOF

{|aField1| &(cArqTmp+"->"+aField1) } )

*

FrPrn:PreviewOptions:SetAllowEdit( .F. )

FrPrn:PreviewOptions:SetZoomMode(2)

FrPrn:PreviewOptions:SetOutlineExpand(.F.)

sambomb · April 15, 2015

Segue um exemplo de como eu defino o acesso a um DBF no Fast

****************************************************************************
FUNCTION ImprimeCarne()
****************************************************************************
Local cDir := "", lProssegue := .F.
local bAction
Private oFrPrn
 
   //-- Gerar objeto Fast-Report
   cDir := DirExe()
 
   oFrPrn := frReportManager():new( cDir + "FRSystH.dll" )
 
   //-- Configurar os campos
   With object oFrPrn
 
      :LoadFromResource("CARNENOVO")
      
      GeraDatabaseFR()
      
      :SetProperty("NomeEmp.Memo", "Text", pEmp:cFantasia)
      :SetProperty("EnderecoEmp.Memo", "Text",  pEmp:cEndereco + " - " +;
                                                pEmp:cCidade + " / " +;
                                                pEmp:cEstado)
      
      //-- Configurar o preview
      :PreviewOptions:SetAllowEdit(.F.)
      :PreviewOptions:SetButtons(1209)
      :PreviewOptions:SetMaximized(.T.)
      
      //-- Preview
      :ShowReport()
      
      //-- Limpa os datasets
      :ClearDataSets()
      
      //-- Fecha/Limpa
      :Clear()
      
      //-- Destrói
      :DestroyFR()
 
   end
 
   Select CARNE
   DbCloseArea()
 
RETURN .T.
/*------------------------------------------------------------------------*/
 
****************************************************************************
static Procedure GeraDatabaseFR()
****************************************************************************
*
* Gerar os bancos de dados em aberto no fast report
* Parametros:
* Retorno: Nenhum
*
* Autor: Samir
* 21/6/2009 - 08:52:17
*
****************************************************************************
 
local aDbf := ListaAlias(), x := 0, y := 0, i := 0
 
   aDbf := ListaAlias()
 
   x := 10 ; y := 20
 
   With object oFrPrn
 
      For i = 1 to Len(aDbf)
 
         If !:SetProperty( aDbf[i], "TableName", pDir + aDbf[i] + ".DBF")
            :CreateFRObject("TFrxHarbourWorkArea","Data",aDbf[i], x, 10, y, 20)
         end
 
         //-- Modificar as propiedades do Data Source Estoque
         :SetProperty( aDbf[i], "TableName", pDir + aDbf[i] + ".DBF")
         :SetProperty( aDbf[i], "UserName", aDbf[i])
         :SetProperty( aDbf[i], "Name", aDbf[i])
         :SetProperty( aDbf[i], "Alias", aDbf[i])
         :SetProperty( aDbf[i], "WorkArea", Select(aDbf[i]) )
         
         //-- Adicionar Data Source ao relatório
         :AddGlobalDsToReport(aDbf[i])
         
         x += 50 ; y += 50
         
      end//-- For i = 1 to Len(aDbf)
         
   end//-- With object oFrPrn
 
Return nil
/*------------------------------------------------------------------------*/
 
****************************************************************************
Function ListaAlias()
****************************************************************************
*
* Listar todos os alias em aberto
* Parametros:
* Retorno: aAlias
*
* Autor: Samir
* 21/7/2009 - 16:53:12
*
****************************************************************************
 
local aAlias := {}, i := 0
 
   i:= 1
 
   If Empty( Alias( i ) )
      Return aAlias
   end
 
   While !Empty( Alias( i ) )
 
      aAdd(aAlias,Upper( AllTrim( Alias( i ) ) ) )
 
      i++
 
   end
 
Return aAlias
 
/*------------------------------------------------------------------------*/

kapiaba · April 15, 2015

Theotokos, para que serve este comando:

FrPrn:PreviewOptions:SetOutlineExpand(.F.)

?

Abs

SISCO · April 16, 2015

Fiz um teste de acordo com THEOTOKOS, mas deu o seguinte erro:

Erro base 1004 class: ´NIL´ has no exported method: SETWORKAREA

SELECT TITULO

DbGoTop()

IF TITULO->(Recno()) == 0

MSGSTOP("Consulta Não Encontrada","Atenção")

RETURN .F.

ENDIF

cImagem1 := ".\IMAGEM\logo.bmp"

RepDir := ".\REPORTS\"

cTitulo := "CONTAS CORRENTE EM ABERTO "

cTipo := "ENTIDADE"

oFrPrn := frReportManager():new()

oFrPrn:SetIcon(1) //ícone da janela do FRH

oFrPrn:SetTitle( cTitulo ) //título da janela do FRH

oFrPrn:SetTitle( cTipo ) //título da janela do FRH

oFrPrn:SetTitle( cImagem1 ) //título da janela do FRH

oFrPrn:LoadLangRes( 'brazil.xml') //arquivo de idioma

*

cArqTmp := "TITULO"

cCampo1 := ""

*

FrPrn:SetWorkArea(cArqTmp, 3, .f., {FR_RB_FIRST, FR_RE_LAST, 0})

FrPrn:SetUserDataSet( cArqTmp,cCampo1,;

{|| DbGoTop() }, ; //--> bGoTop

{|| DbSkip(1) }, ; //--> bSkipPlus

{|| DbSkip(-1)}, ; //--> bSkipMinus

{|| EOF() }, ; //--> bCheckEOF

{|aField1| &(cArqTmp+"->"+aField1) } )

*

FrPrn:PreviewOptions:SetAllowEdit( .F. )

FrPrn:PreviewOptions:SetZoomMode(2)

FrPrn:PreviewOptions:SetOutlineExpand(.F.)

oFrPrn:LoadFromFile(RepDir+"REL_TITABE.FR3") // para leitura direta de arquivo FR3

oFrPrn:PreviewOptions:SetAllowEdit( .f. ) // inibe o botão de edição do relatório pelo usuário

oFrPrn:DesignReport()

oFrPrn:ShowReport()

oFrPrn:DestroyFR()

aferra · April 17, 2015

se o código é o que está no seu fonte então mude isso

FrPrn:SetWorkArea

para isso

oFrPrn:SetWorkArea

Theotokos · April 17, 2015

Fiz um teste de acordo com THEOTOKOS, mas deu o seguinte erro:

Erro base 1004 class: ´NIL´ has no exported method: SETWORKAREA

SELECT TITULO

DbGoTop()

IF TITULO->(Recno()) == 0

MSGSTOP("Consulta Não Encontrada","Atenção")

RETURN .F.

ENDIF

cImagem1 := ".\IMAGEM\logo.bmp"

RepDir := ".\REPORTS\"

cTitulo := "CONTAS CORRENTE EM ABERTO "

cTipo := "ENTIDADE"

oFrPrn := frReportManager():new()

oFrPrn:SetIcon(1) //ícone da janela do FRH

oFrPrn:SetTitle( cTitulo ) //título da janela do FRH

oFrPrn:SetTitle( cTipo ) //título da janela do FRH

oFrPrn:SetTitle( cImagem1 ) //título da janela do FRH

oFrPrn:LoadLangRes( 'brazil.xml') //arquivo de idioma

*

cArqTmp := "TITULO"

cCampo1 := ""

*

oFrPrn:SetWorkArea(cArqTmp, 3, .f., {FR_RB_FIRST, FR_RE_LAST, 0})

oFrPrn:SetUserDataSet( cArqTmp,cCampo1,;

{|| DbGoTop() }, ; //--> bGoTop

{|| DbSkip(1) }, ; //--> bSkipPlus

{|| DbSkip(-1)}, ; //--> bSkipMinus

{|| EOF() }, ; //--> bCheckEOF

{|aField1| &(cArqTmp+"->"+aField1) } )

*

oFrPrn:PreviewOptions:SetAllowEdit( .F. )

oFrPrn:PreviewOptions:SetZoomMode(2)

oFrPrn:PreviewOptions:SetOutlineExpand(.F.)

oFrPrn:LoadFromFile(RepDir+"REL_TITABE.FR3") // para leitura direta de arquivo FR3

oFrPrn:PreviewOptions:SetAllowEdit( .f. ) // inibe o botão de edição do relatório pelo usuário

oFrPrn:DesignReport()

oFrPrn:ShowReport()

oFrPrn:DestroyFR()

Cuidado com CTRL+C CTRL+V........... rsrsrsrsrsr

Sign In

Fastreport com DBF

Recommended Posts

SISCO

Link to comment

Share on other sites

kleyber

Link to comment

Share on other sites

SISCO

Link to comment

Share on other sites

sambomb

Link to comment

Share on other sites

SISCO

Link to comment

Share on other sites

Theotokos

Link to comment

Share on other sites

sambomb

Link to comment

Share on other sites

kapiaba

Link to comment

Share on other sites

SISCO

Link to comment

Share on other sites

aferra

Link to comment

Share on other sites

Theotokos

Link to comment

Share on other sites

Join the conversation

Browse

Activity