TExplorerBar

[kapiaba]

http://imgur.com/wAuKcCq

 

 

http://forums.fivetechsupport.com/viewtopic.php?f=6&t=16517#p204403

 

 

[crisvam]

É uma classe muito boa. Eu já uso-a no meu último sistema.

[marcioe]

Bom dia amigos, tudo bem, teria como dimensionar ela,
Pois fiz uns teste e esta assumindo todo o tamanho da tela

Gostaria  de poder dimensionar, largura e Altua, e a posição inicial.

E tambem se tem como colocar ela dentro de uma dialog gerada no pellesc

 

Obrigado a todos
 

[kapiaba]

Acho que é isso:

http://forums.fivetechsupport.com/viewtopic.php?f=3&t=31871&p=186261&hilit=texplorer#p186261

 

	   oWnd:SetSize( 800, 600 )  // 800x600
	

[kapiaba]

Sua segunda pergunta:

#include "FiveWin.ch"
	//----------------------------------------------------------------------------//
	function Main()
	   local oDlg, oExBar 
      
   DEFINE DIALOG oDlg RESOURCE "Test"
   
   REDEFINE EXPLORERBAR oExBar ID 100 OF oDlg
	   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT ExplBarInit( oExBar )
	return nil
	//----------------------------------------------------------------------------//
	function ExplBarInit( oExBar )
	   local oPanel1, oPanel2, oPanel3, oPanel4
   local bClick := { | o | MsgInfo( o:GetText() ) }
	   oPanel1 = oExBar:AddPanel( "One", "people" )
   oPanel1:lSpecial = .T.
   oPanel1:AddLink( "First item", bClick, "additem" )
   oPanel1:AddLink( "Second item", bClick, "copy" )
      
   oPanel2 = oExBar:AddPanel( "Two", "case" )
   oPanel2:AddLink( "First item", bClick, "adddbf" )
   oPanel2:AddLink( "Second item", bClick, "delete" )
   oPanel2:AddLink( "Third item", bClick, "envelope" )
   oPanel2:AddLink( "Fourth item", bClick, "envelope" )
	   oPanel3 = oExBar:AddPanel( "Three", "graphics" )
   oPanel3:AddLink( "First item", bClick, "adddbf" )
   
   oPanel4 = oExBar:AddPanel( "Four" )
   oPanel4:AddLink( "First item", bClick, "copy" )
   oPanel4:AddLink( "Second item", bClick, "additem" )
	return nil
	//----------------------------------------------------------------------------//
	// RC file
	#include <windows.h>
	#ifndef __64__
   1 24 "WinXP/WindowsXP.Manifest"
#endif
	#ifdef __64__
   1 24 "WinXP/WindowsXP.Manifest64"
#endif 
	Test DIALOG 17, 36, 400, 350
STYLE DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_CAPTION | WS_SYSMENU
CAPTION "FWH Class TExplorerBar"
FONT 8, "MS Sans Serif"
{
 CONTROL "Test", 100, "TEXPLORERBAR", 0 | WS_CHILD | WS_CLIPCHILDREN | WS_VISIBLE, 0, 0, 150, 350
 DEFPUSHBUTTON "OK", 1, 341, 327, 50, 14
}
	people   BITMAP "..\bitmaps\32x32\people.bmp"
case     BITMAP "..\bitmaps\32x32\case.bmp"
graphics BITMAP "..\bitmaps\32x32\graphics.bmp"
additem  BITMAP "..\bitmaps\16x16\additem.bmp"
copy     BITMAP "..\bitmaps\16x16\copy.bmp"
adddbf   BITMAP "..\bitmaps\16x16\adddbf.bmp"
delete   BITMAP "..\bitmaps\16x16\delete0.bmp"
envelope BITMAP "..\bitmaps\16x16\envelope.bmp"

[augustogomes]

Durante muito tempo apanhei pra entender como fazer um painel ou todos, abrir comprimido. Hoje com a ajuda de uns tópicos enviado pelo Kapiaba, consegui fazer.

veja o exemplo anterior abrindo todos os painéis comprimidos.

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function Main()

   local oWnd, oExBar, oPanel1, oPanel2, oPanel3, oPanel4 
   local bClick := { | o | MsgInfo( o:GetText() ) }
   local nFecha:=0,nc:=0
      
   DEFINE WINDOW oWnd TITLE "FWH Class TExplorerBar"
   
   oWnd:SetSize( 350, 600 )

   oExBar = TExplorerBar():New()
   oExBar:nTopColor := RGB( 97, 236, 77 )
   oExBar:nBottomColor := RGB( 97, 236, 77 )

   oPanel1 = oExBar:AddPanel( "One", "..\bitmaps\32x32\people.bmp" )
   oPanel1:lSpecial = .T.   
   oPanel1:AddLink( "First item", bClick, "..\bitmaps\16x16\additem.bmp" )
   oPanel1:AddLink( "Second item", bClick, "..\bitmaps\16x16\copy.bmp" )
      
   oPanel2 = oExBar:AddPanel( "Two", "..\bitmaps\32x32\case.bmp" )
   oPanel2:SetColor( CLR_RED, CLR_MAGENTA)
   oPanel2:AddLink( "First item", bClick, "..\bitmaps\16x16\adddbf.bmp" )
   oPanel2:AddLink( "Second item", bClick, "..\bitmaps\16x16\delete0.bmp" )
   oPanel2:AddLink( "Third item", bClick, "..\bitmaps\16x16\envelope.bmp" )
   oPanel2:AddLink( "Fourth item", bClick, "..\bitmaps\16x16\copy.bmp" )

   oPanel3 = oExBar:AddPanel( "Three", "..\bitmaps\32x32\graphics.bmp" )
   oPanel3:AddLink( "First item", bClick, "..\bitmaps\16x16\adddbf.bmp" )
   oPanel3:AddLink( "Second item", bClick, "..\bitmaps\16x16\delete0.bmp" )
   oPanel3:AddLink( "Third item", bClick, "..\bitmaps\16x16\envelope.bmp" )
   
   oPanel4 = oExBar:AddPanel( "Four" )
   oPanel4:AddLink( "First item", bClick, "..\bitmaps\16x16\additem.bmp" )
   oPanel4:AddLink( "Second item", bClick, "..\bitmaps\16x16\copy.bmp" )
 
oExBar:Refresh()


// Comprime todos os paineis
for nFecha:=1 to 4
	oExBar:aPanels[nFecha]:nHeight = oExBar:aPanels[nFecha]:nTitleHeight
	For nC:=nFecha+1 To Len (oExBar:aPanels)
	  oExBar:aPanels[nC]:nTop -= oExBar:aPanels[nFecha]:nBodyHeight
	Next     
	oExBar:aPanels[nFecha]:lCollapsed:=.T.   // muda o icone de expandido para comprimido
next	
   oWnd:oClient = oExBar
   
   ACTIVATE WINDOW oWnd

return nil

//----------------------------------------------------------------------------//
 

 

[kapiaba]

Very good Augusto, many thanks!

 

 

abs.